/*
clipboard.ahk
コマンドライン引数に渡した文字列をそのままクリップボードに入れる

第一引数に何も指定しない場合はそのまま格納
第二引数にオプションを指定した場合は、
オプションに対応した処理を行ってから格納する。

オプション名は必ず先頭にハイフンを付けること。
先頭にハイフンが入った文字列を格納したい場合は
-nを利用するか、文字列以外の引数を渡さなければよい。

%0% コマンドライン引数の数
%1% 第一引数
%2% 第二引数
%3% ...

*/

/*
Opera menu.ini 登録用サンプル
ディレクトリ名を一括置換するなどして利用するといいだろう。

[Document Popup Menu]以下に追加
Item, "ページタイトルをコピー" = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_t %u"
Item, "タイトルとURLをコピー"  = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_tu %u"
Item, "ページのアンカーを作成" = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_anch %u"
Item, "Markdown Anchor"        = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_anch %u"

[Link Popup Menu]以下に追加
Item, "リンクからアンカーを作成"             = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_li %l %u"
Item, "リンクからアンカーを作成(参照元付き)" = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_li_via %l %u"
Item, "Markdown Link Anchor"                 = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_li %l %u"
Item, "Markdown Link Anchor(via)"            = Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_li_via %l %u"

[Hotclick Popup Menu]以下に追加
Item, "選択テキストとURLをコピー"              = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_sel_url %l %u"
Item, "選択テキストからページのアンカーを作成" = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_sel_anch %l %u"
Item, "Markdown SelText Anchor"                = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_sel_anch %l %u"
Item, "コードブロックを作成"                   = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_code %u"
Item, "Markdown Code Block"                    = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_code %u"
Item, "引用"                                   = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_bq %u"
Item, "引用元を付けて引用"                     = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_bq_cite %u"
Item, "Markdown Blockquote"                    = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_bq %u"
Item, "Markdown Blockquote(cite)"              = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_bq_cite %u"
Item, "改行で順序無しリストを作成"             = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_ulist %u"
Item, "改行で順序有りリストを作成"             = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_olist %u"
Item, "Markdown Unordered List"                = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_ulist %u"
Item, "Markdown Ordered List"                  = Copy & Execute program, "C:\ahk\AutoHotkey.exe", "C:\ahk\clipboard.ahk -op_md_olist %u"
*/

#NoTrayIcon ;トレイアイコン非表示
#EscapeChar \ ;エスケープ文字変更

ArgLength = %0%
ClipText = %clipboard%
Option = %1%
Title =
Date = %A_YYYY%-%A_MM%-%A_DD% %A_Hour%:%A_Min%:%A_Sec%

/*
ClipText
%ClipText%で現在のクリップボードの内容=選択した文字列を参照

Title
%Title%でアクティブウインドウのタイトルから後ろ八文字、" - Opera"を除いたタイトルを参照

Date
%Date%で"2006-11-20 11:30:25"のような形式で現在の日付と時刻を参照
*/

;ただのクリップボードにコピー
if ArgLength = 1
	clipboard = %1%
else if ArgLength = 0
	Exit

;ただのクリップボードにコピー
if Option = -n
{
	clipboard = %2%
	Exit
}

;以下Opera用

;opera用オプションが付いているならアクティブウインドウのタイトルを取得(%Title%)
IfInString, Option, -op_
{
	;アクティブウインドウのタイトルを取得
	WinGetTitle, Title, A
	StringTrimRight, Title, Title, 8
}

 

;[Document Popup Menu]以下に追加

;ページタイトルをコピー
if Option = -op_t
{
	clipboard = %Title%
}

;タイトルとURLをコピー
;タイトル\r\nURL
if Option = -op_tu
{
	clipboard = %Title%\r\n%2%
}

;ページのアンカーを作成
;<a href="ページURL">ページタイトル</a>
else if Option = -op_anch
{
	clipboard = <a href="%2%">%Title%</a>
}

 

;[Link Popup Menu]以下に追加

;リンクからアンカー作成
;<a href="リンクURL">リンクURL</a>
else if Option = -op_li
{
	clipboard = <a href="%2%">%2%</a>
}

;リンクからアンカー作成（参照元付き）
;<a href="リンクURL">リンクURL</a>(via <a href="ページURL">ページタイトル</a>)
else if Option = -op_li_via
{
	clipboard = <a href="%2%">%2%</a>(via <a href="%3%">%Title%</a>)
}

 

;[Hotclick Popup Menu]以下に追加

;選択テキストとURLをコピー
;選択テキスト\r\nURL
else if Option = -op_sel_url
{
	clipboard = %ClipText%\r\n%2%
}

;選択テキストからページのアンカーを作成
;<a href="ページURL">選択テキスト</a>
else if Option = -op_sel_anch
{
	clipboard = <a href="%2%">%ClipText%</a>
}

;コードブロックを作成
;<pre><code>選択テキスト</code><pre>
else if Option = -op_code
{
	clipboard = <pre><code>%ClipText%</code><pre>
}

;引用
;<blockquote cite="ページURL" title="ページタイトル"><p>選択テキスト</p></blockquote>
else if Option = -op_bq
{
	;全ての改行(\r\n)の後に<br />を付ける
	StringReplace, ClipText, ClipText, \r\n, \r\n<br />, All
	clipboard = <blockquote cite="%2%" title="%Title%">\r\n<p>%ClipText%</p>\r\n</blockquote>
}

;引用元を付けて引用
;<blockquote cite="ページURL" title="ページタイトル">
;<p>選択テキスト</p>
;<p><cite><a href="ページURL">ページタイトル</a></cite></p>
;</blockquote>
else if Option = -op_bq_cite
{
	;全ての改行(\r\n)の後に<br />を付ける
	StringReplace, ClipText, ClipText, \r\n, \r\n<br />, All
	clipboard = <blockquote cite="%2%" title="%Title%">\r\n<p>%ClipText%</p>\r\n<p><cite><a href="%2%">%Title%</a></cite></p>\r\n</blockquote>
}

;改行で順序無しリストを作成
else if Option = -op_ulist
{
	;2つ以上連続した改行を1つにして、改行を</li><li>に変換
	BQText := RegExReplace( ClipText, "(\r\n)+", "</li>\r\n<li>")
	clipboard = <ul>\r\n<li>%BQText%</li>\r\n</ul>
}

;改行で順序有りリストを作成
else if Option = -op_olist
{
	;2つ以上連続した改行を1つにして、改行を</li><li>に変換
	BQText := RegExReplace( ClipText, "(\r\n)+", "</li>\r\n<li>")
	clipboard = <ol>\r\n<li>%BQText%</li>\r\n</ol>
}

 

;Markdown形式

;Markdown Anchor
else if Option = -op_md_anch
{
	clipboard = [%Title%](%2%)
}

;Markdown Link Anchor
else if Option = -op_md_li
{
	clipboard = [%2%](%2%)
}

;Markdown Link Anchor(via)
else if Option = -op_md_li_via
{
	clipboard = [%2%](%2%)([%Title%](%3%))
}

;Markdown SelText Anchor
else if Option = -op_md_sel_anch
{
	clipboard = [%2%](%ClipText%)
}

;Markdown Code Block
else if Option = -op_md_code
{
	;最後の文頭タブがAutoTrimで消されるのでOFFにしとく
	AutoTrim, Off
	StringReplace, ClipText, ClipText, \r\n, \r\n%A_Tab%, All
	clipboard = %A_Tab%%ClipText%
}

;Markdown Blockquote
else if Option = -op_md_bq
{
	StringReplace, ClipText, ClipText, \r\n, %A_Space%%A_Space%\r\n>, All
	clipboard = >%ClipText%
}

;Markdown Blockquote(cite)
else if Option = -op_md_bq_cite
{
	StringReplace, ClipText, ClipText, \r\n, %A_Space%%A_Space%\r\n>, All
	clipboard = >%ClipText%\r\n>\r\n><cite>[%Title%](%2%)</cite>
}

;Markdown Unordered List
else if Option = -op_md_ulist
{
	;2つ以上連続した改行を1つにして、改行の後に*を追加
	BQText := RegExReplace( ClipText, "(\r\n)+", "\r\n* ")
	clipboard = * %BQText%
}

;Markdown Ordered List
else if Option = -op_md_olist
{
	;Parseは1バイト区切りなので、全ての1つ以上連続した\r\nを\rに変換
	olText := RegExReplace( ClipText, "(\r\n)+", "\r")
	
	Loop, parse, olText, \r,
	{
		md_OlText = %md_OlText%%A_Index%. %A_LoopField%\r
	}
	
	;\rを\r\nに戻す
	StringReplace, md_OlText, md_OlText, \r, \r\n, All
	clipboard = %md_OlText%
}